9f807cd0df
Summary: This diff only moves the core of sonarkit to the xplat. - This diff uses `fb_xplat_cxx_library` as a buck rule in xplat as it is the recommended way - Updated few imports in the files which were not compiling with new buck function - Due to the new way of import the OSS would break, so fixed it by changing the `podspec` file Reviewed By: passy Differential Revision: D8937414 fbshipit-source-id: 6e12cd049bedb496e7a6820be85b2535e70ba09b
49 lines
1.4 KiB
Objective-C
49 lines
1.4 KiB
Objective-C
/*
|
|
* Copyright (c) 2018-present, Facebook, Inc.
|
|
*
|
|
* This source code is licensed under the MIT license found in the LICENSE
|
|
* file in the root directory of this source tree.
|
|
*
|
|
*/
|
|
#ifndef __OBJC__
|
|
#error This header can only be included in .mm (ObjC++) files
|
|
#endif
|
|
|
|
#import <Sonar/SonarPlugin.h>
|
|
#import <SonarKit/CppBridge/SonarCppBridgingConnection.h>
|
|
#import <SonarKit/SonarPlugin.h>
|
|
|
|
namespace facebook {
|
|
namespace sonar {
|
|
|
|
using ObjCPlugin = NSObject<SonarPlugin> *;
|
|
|
|
/**
|
|
SonarCppWrapperPlugin is a simple C++ wrapper around Objective-C Sonar plugins
|
|
that can be passed to SonarClient. This class allows developers to write pure
|
|
Objective-C plugins if they want.
|
|
*/
|
|
class SonarCppWrapperPlugin final : public facebook::sonar::SonarPlugin {
|
|
public:
|
|
// Under ARC copying objCPlugin *does* increment its retain count
|
|
SonarCppWrapperPlugin(ObjCPlugin objCPlugin) : _objCPlugin(objCPlugin) {}
|
|
|
|
std::string identifier() const override { return [[_objCPlugin identifier] UTF8String]; }
|
|
|
|
void didConnect(std::shared_ptr<facebook::sonar::SonarConnection> conn) override
|
|
{
|
|
SonarCppBridgingConnection *const bridgingConn = [[SonarCppBridgingConnection alloc] initWithCppConnection:conn];
|
|
[_objCPlugin didConnect:bridgingConn];
|
|
}
|
|
|
|
void didDisconnect() override { [_objCPlugin didDisconnect]; }
|
|
|
|
ObjCPlugin getObjCPlugin() { return _objCPlugin; }
|
|
|
|
private:
|
|
ObjCPlugin _objCPlugin;
|
|
};
|
|
|
|
} // namespace sonar
|
|
} // namespace facebook
|