aa649ff48f
Summary: `/*` is the standard throughout open source code. For example, Firefox uses single /*: https://hg.mozilla.org/mozilla-central/file/21d22b2f541258d3d1cf96c7ba5ad73e96e616b5/gfx/ipc/CompositorWidgetVsyncObserver.cpp#l3 In addition, Rust considers `/**` to be a doc comment (similar to Javadoc) and having such a comment at the beginning of the file causes `rustc` to barf. Note that some JavaScript tooling requires `/**`. This is OK since JavaScript files were not covered by the linter in the first place, but it would be good to have that tooling fixed too. Reviewed By: zertosh Differential Revision: D15640366 fbshipit-source-id: b4ed4599071516364d6109720750d6a43304c089
55 lines
1.6 KiB
Objective-C
55 lines
1.6 KiB
Objective-C
/*
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the LICENSE
|
|
* file in the root directory of this source tree.
|
|
*/
|
|
#ifndef __OBJC__
|
|
#error This header can only be included in .mm (ObjC++) files
|
|
#endif
|
|
|
|
#import <Flipper/FlipperPlugin.h>
|
|
#import <FlipperKit/CppBridge/FlipperCppBridgingConnection.h>
|
|
#import <FlipperKit/FlipperPlugin.h>
|
|
|
|
namespace facebook {
|
|
namespace flipper {
|
|
|
|
using ObjCPlugin = NSObject<FlipperPlugin> *;
|
|
|
|
/**
|
|
SonarCppWrapperPlugin is a simple C++ wrapper around Objective-C Sonar plugins
|
|
that can be passed to SonarClient. This class allows developers to write pure
|
|
Objective-C plugins if they want.
|
|
*/
|
|
class FlipperCppWrapperPlugin final : public facebook::flipper::FlipperPlugin {
|
|
public:
|
|
// Under ARC copying objCPlugin *does* increment its retain count
|
|
FlipperCppWrapperPlugin(ObjCPlugin objCPlugin) : _objCPlugin(objCPlugin) {}
|
|
|
|
std::string identifier() const override { return [[_objCPlugin identifier] UTF8String]; }
|
|
|
|
void didConnect(std::shared_ptr<facebook::flipper::FlipperConnection> conn) override
|
|
{
|
|
FlipperCppBridgingConnection *const bridgingConn = [[FlipperCppBridgingConnection alloc] initWithCppConnection:conn];
|
|
[_objCPlugin didConnect:bridgingConn];
|
|
}
|
|
|
|
void didDisconnect() override { [_objCPlugin didDisconnect]; }
|
|
|
|
bool runInBackground() override {
|
|
if ([_objCPlugin respondsToSelector:@selector(runInBackground)]) {
|
|
return [_objCPlugin runInBackground];
|
|
}
|
|
return false;
|
|
}
|
|
|
|
ObjCPlugin getObjCPlugin() { return _objCPlugin; }
|
|
|
|
private:
|
|
ObjCPlugin _objCPlugin;
|
|
};
|
|
|
|
} // namespace flipper
|
|
} // namespace facebook
|