5bbfa58909
Summary: This diff sets up flipper for running plugins in background. This diff does the following - Adds a function named `runInBackground` to the interface `FlipperPlugin` to make the plugins opt in to be run in background, default is false - Changes the javascript side of the flipper to store the messages received by the plugins in background - Process the stored messages when the plugin in background becomes active - Currently I have just turned on network plugin to be in background mode. - Remove the buffering from the network plugin, as it will run in background - Write a batching layer to batch the messages and send to flipper. Note: I haven't tested the wilde app yet, but the sample app works. I will remove the "[WIP]" from the title once I have tested it in wilde Reviewed By: danielbuechele Differential Revision: D10301403 fbshipit-source-id: 034eebf659a545d6b480a4ac1b73b0aa4b2f9797
56 lines
1.6 KiB
Objective-C
56 lines
1.6 KiB
Objective-C
/*
|
|
* Copyright (c) 2018-present, Facebook, Inc.
|
|
*
|
|
* This source code is licensed under the MIT license found in the LICENSE
|
|
* file in the root directory of this source tree.
|
|
*
|
|
*/
|
|
#ifndef __OBJC__
|
|
#error This header can only be included in .mm (ObjC++) files
|
|
#endif
|
|
|
|
#import <Flipper/FlipperPlugin.h>
|
|
#import <FlipperKit/CppBridge/FlipperCppBridgingConnection.h>
|
|
#import <FlipperKit/FlipperPlugin.h>
|
|
|
|
namespace facebook {
|
|
namespace flipper {
|
|
|
|
using ObjCPlugin = NSObject<FlipperPlugin> *;
|
|
|
|
/**
|
|
SonarCppWrapperPlugin is a simple C++ wrapper around Objective-C Sonar plugins
|
|
that can be passed to SonarClient. This class allows developers to write pure
|
|
Objective-C plugins if they want.
|
|
*/
|
|
class FlipperCppWrapperPlugin final : public facebook::flipper::FlipperPlugin {
|
|
public:
|
|
// Under ARC copying objCPlugin *does* increment its retain count
|
|
FlipperCppWrapperPlugin(ObjCPlugin objCPlugin) : _objCPlugin(objCPlugin) {}
|
|
|
|
std::string identifier() const override { return [[_objCPlugin identifier] UTF8String]; }
|
|
|
|
void didConnect(std::shared_ptr<facebook::flipper::FlipperConnection> conn) override
|
|
{
|
|
FlipperCppBridgingConnection *const bridgingConn = [[FlipperCppBridgingConnection alloc] initWithCppConnection:conn];
|
|
[_objCPlugin didConnect:bridgingConn];
|
|
}
|
|
|
|
void didDisconnect() override { [_objCPlugin didDisconnect]; }
|
|
|
|
bool runInBackground() override {
|
|
if ([_objCPlugin respondsToSelector:@selector(runInBackground)]) {
|
|
return [_objCPlugin runInBackground];
|
|
}
|
|
return false;
|
|
}
|
|
|
|
ObjCPlugin getObjCPlugin() { return _objCPlugin; }
|
|
|
|
private:
|
|
ObjCPlugin _objCPlugin;
|
|
};
|
|
|
|
} // namespace flipper
|
|
} // namespace facebook
|