5bbfa58909
Summary: This diff sets up flipper for running plugins in background. This diff does the following - Adds a function named `runInBackground` to the interface `FlipperPlugin` to make the plugins opt in to be run in background, default is false - Changes the javascript side of the flipper to store the messages received by the plugins in background - Process the stored messages when the plugin in background becomes active - Currently I have just turned on network plugin to be in background mode. - Remove the buffering from the network plugin, as it will run in background - Write a batching layer to batch the messages and send to flipper. Note: I haven't tested the wilde app yet, but the sample app works. I will remove the "[WIP]" from the title once I have tested it in wilde Reviewed By: danielbuechele Differential Revision: D10301403 fbshipit-source-id: 034eebf659a545d6b480a4ac1b73b0aa4b2f9797
112 lines
2.7 KiB
Plaintext
112 lines
2.7 KiB
Plaintext
/*
|
|
* Copyright (c) 2018-present, Facebook, Inc.
|
|
*
|
|
* This source code is licensed under the MIT license found in the LICENSE
|
|
* file in the root directory of this source tree.
|
|
*
|
|
*/
|
|
#if FB_SONARKIT_ENABLED
|
|
|
|
#import <vector>
|
|
|
|
#import "SKBufferingPlugin.h"
|
|
#import <FlipperKit/FlipperConnection.h>
|
|
#import "SKDispatchQueue.h"
|
|
#import "SKBufferingPlugin+CPPInitialization.h"
|
|
|
|
static const NSUInteger bufferSize = 500;
|
|
|
|
@interface SKBufferingPlugin()
|
|
|
|
@property(assign, nonatomic) std::vector<CachedEvent> ringBuffer;
|
|
@property(assign, nonatomic) std::shared_ptr<facebook::flipper::DispatchQueue> connectionAccessQueue;
|
|
@property(strong, nonatomic) id<FlipperConnection> connection;
|
|
|
|
@end
|
|
|
|
@implementation SKBufferingPlugin
|
|
// {
|
|
// std::vector<CachedEvent> _ringBuffer;
|
|
// std::shared_ptr<facebook::flipper::DispatchQueue> _connectionAccessQueue;
|
|
//
|
|
// id<FlipperConnection> _connection;
|
|
// }
|
|
|
|
- (instancetype)initWithQueue:(dispatch_queue_t)queue {
|
|
if (self = [super init]) {
|
|
_ringBuffer.reserve(bufferSize);
|
|
_connectionAccessQueue = std::make_shared<facebook::flipper::GCDQueue>(queue);
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (NSString *)identifier {
|
|
// Note: This must match with the javascript pulgin identifier!!
|
|
return @"Network";
|
|
}
|
|
|
|
- (void)didConnect:(id<FlipperConnection>)connection {
|
|
_connectionAccessQueue->async(^{
|
|
self->_connection = connection;
|
|
[self sendBufferedEvents];
|
|
});
|
|
}
|
|
|
|
- (void)didDisconnect {
|
|
_connectionAccessQueue->async(^{
|
|
self->_connection = nil;
|
|
});
|
|
}
|
|
|
|
- (BOOL)runInBackground {
|
|
return YES;
|
|
}
|
|
|
|
|
|
- (void)send:(NSString *)method
|
|
sonarObject:(NSDictionary<NSString *, id> *)sonarObject {
|
|
_connectionAccessQueue->async(^{
|
|
if (self->_connection) {
|
|
[self->_connection send:method withParams:sonarObject];
|
|
} else {
|
|
if (self->_ringBuffer.size() == bufferSize) {
|
|
return;
|
|
}
|
|
self->_ringBuffer.push_back({
|
|
.method = method,
|
|
.sonarObject = sonarObject
|
|
});
|
|
}
|
|
});
|
|
}
|
|
|
|
- (void)sendBufferedEvents {
|
|
NSAssert(_connection, @"connection object cannot be nil");
|
|
for (const auto &event : _ringBuffer) {
|
|
[_connection send:event.method withParams:event.sonarObject];
|
|
}
|
|
_ringBuffer.clear();
|
|
}
|
|
|
|
@end
|
|
|
|
@implementation SKBufferingPlugin(CPPInitialization)
|
|
|
|
- (instancetype)initWithVectorEventSize:(NSUInteger)size connectionAccessQueue:(std::shared_ptr<facebook::flipper::DispatchQueue>)connectionAccessQueue {
|
|
if (self = [super init]) {
|
|
_ringBuffer.reserve(size);
|
|
_connectionAccessQueue = connectionAccessQueue;
|
|
}
|
|
return self;
|
|
}
|
|
- (instancetype)initWithDispatchQueue:(std::shared_ptr<facebook::flipper::DispatchQueue>)queue {
|
|
return [self initWithVectorEventSize:bufferSize
|
|
connectionAccessQueue:queue];
|
|
|
|
}
|
|
|
|
@end
|
|
|
|
|
|
#endif
|