Back out "Revert D30371791"

Summary: This change reverts a revert. The change was reverted for 'unrelated' issues addressed on this diff dependencies.

Reviewed By: passy

Differential Revision: D30696113

fbshipit-source-id: 8591d6ea79999597024c316e9927a346979e5219

iOS/FlipperKit/FlipperClient.mm

@@ -10,12 +10,14 @@
 #import "FlipperClient.h"
 #import <Flipper/FlipperCertificateProvider.h>
 #import <Flipper/FlipperClient.h>
+#import <Flipper/FlipperSocketProvider.h>
 #include <folly/io/async/EventBase.h>
 #include <folly/io/async/ScopedEventBaseThread.h>
 #include <memory>
 #import "FlipperClient+Testing.h"
 #import "FlipperCppWrapperPlugin.h"
 #import "FlipperKitCertificateProvider.h"
+#import "FlipperWebSocket.h"
 #import "SKEnvironmentVariables.h"
 #include "SKStateUpdateCPPWrapper.h"
 
@@ -101,6 +103,11 @@ using WrapperPlugin = facebook::flipper::FlipperCppWrapperPlugin;
            [SKEnvironmentVariables getInsecurePort],
            [SKEnvironmentVariables getSecurePort]});
       _cppClient = facebook::flipper::FlipperClient::instance();
+
+      // To switch to a websocket provider, uncomment the line below.
+      // facebook::flipper::FlipperSocketProvider::setDefaultProvider(
+      //     std::make_unique<facebook::flipper::FlipperWebSocketProvider>());
+
     } catch (const std::system_error& e) {
       // Probably ran out of disk space.
       return nil;

iOS/FlipperKit/FlipperPlatformWebSocket.h

@@ -0,0 +1,53 @@
+/*
+ * Copyright (c) Facebook, Inc. and its affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#ifdef FB_SONARKIT_ENABLED
+
+#import <Flipper/FlipperTransportTypes.h>
+#import <Foundation/Foundation.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+/// Defines a WebSocket transport to be used by Flipper. It just acts as a
+/// wrapper on top of a WebSocket connection mainly used to abstract the actual
+/// used implementation.
+@interface FlipperPlatformWebSocket : NSObject
+
+/// An event handler used to dispatch socket events to the caller.
+@property(nonatomic) facebook::flipper::SocketEventHandler eventHandler;
+
+/// A message handler used to dispatch messages received from the server.
+@property(nonatomic) facebook::flipper::SocketMessageHandler messageHandler;
+
+/// A certificate provider used to obtain the client certificate used for
+/// authentication.
+@property(nonatomic)
+    facebook::flipper::SocketCertificateProvider certificateProvider;
+
+/// Initializes an instance of FliperWebSocketTransport with an endpoint URL.
+/// @param url Endpoint URL used to establish the connection.
+- (instancetype)initWithURL:(NSURL* _Nonnull)url;
+
+/// Connect to the endpoint.
+- (void)connect;
+
+/// Disconnects from the endpoint.
+- (void)disconnect;
+
+/// Send a message to the endpoint.
+/// @param message The message as text to be sent to the endpoint.
+/// @param error  A pointer to variable for an `NSError` object.
+/// If an error occurs, the pointer is set to an `NSError` object containing
+/// information about the error. You may specify `nil` to ignore the error
+/// information.
+- (void)send:(NSString*)message error:(NSError**)error;
+
+@end
+
+NS_ASSUME_NONNULL_END
+
+#endif

iOS/FlipperKit/FlipperPlatformWebSocket.mm

@@ -0,0 +1,219 @@
+/*
+ * Copyright (c) Facebook, Inc. and its affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#ifdef FB_SONARKIT_ENABLED
+
+#import "FlipperPlatformWebSocket.h"
+#import <Flipper/Log.h>
+#import <SocketRocket/SocketRocket.h>
+
+static constexpr int connectionKeepaliveSeconds = 10;
+
+#pragma mark - FlipperClientCertificateSecurityPolicy
+
+@interface FlipperClientCertificateSecurityPolicy : SRSecurityPolicy
+
+@property(nonatomic)
+    facebook::flipper::SocketCertificateProvider certificateProvider;
+
+- (id)initWithCertificateProvider:
+    (facebook::flipper::SocketCertificateProvider)certificateProvider;
+
+@end
+
+@implementation FlipperClientCertificateSecurityPolicy
+
+- (id)initWithCertificateProvider:
+    (facebook::flipper::SocketCertificateProvider)certificateProvider {
+  self = [super init];
+
+  if (self) {
+    _certificateProvider = certificateProvider;
+  }
+
+  return self;
+}
+
+/**
+ Updates all the security options for  output streams, used for client
+ certificate authentication.
+
+ @param stream Stream to update the options in.
+ */
+- (void)updateSecurityOptionsInStream:(NSStream*)stream {
+  if (!_certificateProvider || ![stream isKindOfClass:[NSOutputStream class]]) {
+    return;
+  }
+
+  NSMutableDictionary* SSLOptions = [[NSMutableDictionary alloc] init];
+  [stream setProperty:(__bridge id)kCFStreamSocketSecurityLevelNegotiatedSSL
+               forKey:(__bridge id)kCFStreamPropertySocketSecurityLevel];
+
+  char PASSWORD[512] = {};
+  auto certificatePath = _certificateProvider(&PASSWORD[0], 512);
+
+  NSString* certificatePathObjC =
+      [NSString stringWithUTF8String:certificatePath.c_str()];
+  NSData* certificateData = [NSData dataWithContentsOfFile:certificatePathObjC];
+
+  NSString* password = [NSString stringWithUTF8String:PASSWORD];
+  NSDictionary* optionsDictionary = [NSDictionary
+      dictionaryWithObject:password
+                    forKey:(__bridge id)kSecImportExportPassphrase];
+
+  CFArrayRef items = NULL;
+  OSStatus status = SecPKCS12Import(
+      (__bridge CFDataRef)certificateData,
+      (__bridge CFDictionaryRef)optionsDictionary,
+      &items);
+  if (status != noErr) {
+    return;
+  }
+
+  CFDictionaryRef identityDictionary =
+      (CFDictionaryRef)CFArrayGetValueAtIndex(items, 0);
+  SecIdentityRef identity = (SecIdentityRef)CFDictionaryGetValue(
+      identityDictionary, kSecImportItemIdentity);
+
+  SecCertificateRef certificate = NULL;
+  status = SecIdentityCopyCertificate(identity, &certificate);
+
+  if (status != noErr) {
+    return;
+  }
+
+  NSArray* certificates = [[NSArray alloc]
+      initWithObjects:(__bridge id)identity, (__bridge id)certificate, nil];
+
+  [SSLOptions setObject:[NSNumber numberWithBool:NO]
+                 forKey:(NSString*)kCFStreamSSLValidatesCertificateChain];
+  [SSLOptions setObject:(NSString*)kCFStreamSocketSecurityLevelNegotiatedSSL
+                 forKey:(NSString*)kCFStreamSSLLevel];
+  [SSLOptions setObject:(NSString*)kCFStreamSocketSecurityLevelNegotiatedSSL
+                 forKey:(NSString*)kCFStreamPropertySocketSecurityLevel];
+  [SSLOptions setObject:certificates
+                 forKey:(NSString*)kCFStreamSSLCertificates];
+  [SSLOptions setObject:[NSNumber numberWithBool:NO]
+                 forKey:(NSString*)kCFStreamSSLIsServer];
+
+  [stream setProperty:SSLOptions
+               forKey:(__bridge id)kCFStreamPropertySSLSettings];
+}
+
+@end
+
+#pragma mark - FlipperPlatformWebSocket
+
+@interface FlipperPlatformWebSocket ()<SRWebSocketDelegate> {
+  NSURL* _url;
+  NSTimer* _keepAlive;
+
+  FlipperClientCertificateSecurityPolicy* _policy;
+}
+
+@property(nonatomic, strong) SRWebSocket* socket;
+
+@end
+
+@implementation FlipperPlatformWebSocket
+
+- (instancetype)initWithURL:(NSURL* _Nonnull)url {
+  self = [super init];
+  if (self) {
+    _url = url;
+    _policy = [FlipperClientCertificateSecurityPolicy new];
+  }
+
+  return self;
+}
+
+- (void)dealloc {
+  [self disconnect];
+}
+
+- (void)connect {
+  if (_socket) {
+    return;
+  }
+
+  self.socket = [[SRWebSocket alloc] initWithURL:_url securityPolicy:_policy];
+  [_socket setDelegate:self];
+  [_socket open];
+}
+
+- (void)disconnect {
+  if ([_keepAlive isValid]) {
+    [_keepAlive invalidate];
+  }
+  _keepAlive = nil;
+
+  if (_socket) {
+    // Manually trigger a 'close' event as SocketRocket close method will
+    // not notify the delegate. SocketRocket only triggers the close event
+    // when the connection is closed from the server.
+    _eventHandler(facebook::flipper::SocketEvent::CLOSE);
+
+    [_socket close];
+    _socket = nil;
+  }
+}
+
+- (void)send:(NSString*)message error:(NSError**)error {
+  [_socket sendString:message error:error];
+  if (error != nil && *error) {
+    facebook::flipper::log("Unable to send message.");
+  }
+}
+
+- (void)setCertificateProvider:
+    (facebook::flipper::SocketCertificateProvider)certificateProvider {
+  _certificateProvider = certificateProvider;
+  _policy.certificateProvider = certificateProvider;
+}
+
+- (void)sendScheduledKeepAlive:(NSTimer*)timer {
+  [_socket sendPing:nil error:nil];
+}
+
+- (void)webSocketDidOpen:(SRWebSocket*)webSocket {
+  _eventHandler(facebook::flipper::SocketEvent::OPEN);
+
+  if (!_keepAlive) {
+    __weak auto weakSocket = _socket;
+    _keepAlive =
+        [NSTimer scheduledTimerWithTimeInterval:connectionKeepaliveSeconds
+                                        repeats:YES
+                                          block:^(NSTimer* timer) {
+                                            auto _Nullable socket = weakSocket;
+                                            [socket sendPing:nil error:nil];
+                                          }];
+  }
+}
+
+- (void)webSocket:(SRWebSocket*)webSocket didFailWithError:(NSError*)error {
+  _eventHandler(facebook::flipper::SocketEvent::ERROR);
+  _socket = nil;
+}
+
+- (void)webSocket:(SRWebSocket*)webSocket
+    didCloseWithCode:(NSInteger)code
+              reason:(NSString*)reason
+            wasClean:(BOOL)wasClean {
+  _eventHandler(facebook::flipper::SocketEvent::CLOSE);
+  _socket = nil;
+}
+
+- (void)webSocket:(SRWebSocket*)webSocket didReceiveMessage:(id)message {
+  if (message && _messageHandler) {
+    NSString* response = message;
+    _messageHandler([response UTF8String]);
+  }
+}
+
+@end
+
+#endif

iOS/FlipperKit/FlipperWebSocket.h

@@ -0,0 +1,93 @@
+/*
+ * Copyright (c) Facebook, Inc. and its affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#ifdef FB_SONARKIT_ENABLED
+
+#pragma once
+
+#import <Flipper/FlipperSocket.h>
+#import <Flipper/FlipperSocketProvider.h>
+#import <Flipper/FlipperTransportTypes.h>
+#import <folly/dynamic.h>
+#import <folly/io/async/EventBase.h>
+#import <future>
+#import <memory>
+
+@class FlipperPlatformWebSocket;
+
+namespace facebook {
+namespace flipper {
+
+class FlipperConnectionManager;
+class ConnectionContextStore;
+class FlipperWebSocket : public FlipperSocket {
+ public:
+  FlipperWebSocket(
+      FlipperConnectionEndpoint endpoint,
+      std::unique_ptr<FlipperSocketBasePayload> payload,
+      folly::EventBase* eventBase);
+  FlipperWebSocket(
+      FlipperConnectionEndpoint endpoint,
+      std::unique_ptr<FlipperSocketBasePayload> payload,
+      folly::EventBase* eventBase,
+      ConnectionContextStore* connectionContextStore);
+
+  virtual ~FlipperWebSocket() {}
+
+  virtual void setEventHandler(SocketEventHandler eventHandler) override;
+  virtual void setMessageHandler(SocketMessageHandler messageHandler) override;
+
+  virtual bool connect(FlipperConnectionManager* manager) override;
+  virtual void disconnect() override;
+
+  virtual void send(const folly::dynamic& message, SocketSendHandler completion)
+      override;
+  virtual void send(const std::string& message, SocketSendHandler completion)
+      override;
+  virtual void sendExpectResponse(
+      const std::string& message,
+      SocketSendExpectResponseHandler completion) override;
+
+ private:
+  FlipperConnectionEndpoint endpoint_;
+  std::unique_ptr<FlipperSocketBasePayload> payload_;
+  folly::EventBase* eventBase_;
+  ConnectionContextStore* connectionContextStore_;
+
+  FlipperPlatformWebSocket* socket_;
+
+  SocketEventHandler eventHandler_;
+  SocketMessageHandler messageHandler_;
+};
+
+class FlipperWebSocketProvider : public FlipperSocketProvider {
+ public:
+  FlipperWebSocketProvider() {}
+  virtual std::unique_ptr<FlipperSocket> create(
+      FlipperConnectionEndpoint endpoint,
+      std::unique_ptr<FlipperSocketBasePayload> payload,
+      folly::EventBase* eventBase) override {
+    return std::make_unique<FlipperWebSocket>(
+        std::move(endpoint), std::move(payload), eventBase);
+  }
+  virtual std::unique_ptr<FlipperSocket> create(
+      FlipperConnectionEndpoint endpoint,
+      std::unique_ptr<FlipperSocketBasePayload> payload,
+      folly::EventBase* eventBase,
+      ConnectionContextStore* connectionContextStore) override {
+    return std::make_unique<FlipperWebSocket>(
+        std::move(endpoint),
+        std::move(payload),
+        eventBase,
+        connectionContextStore);
+  }
+};
+
+} // namespace flipper
+} // namespace facebook
+
+#endif

iOS/FlipperKit/FlipperWebSocket.mm

@@ -0,0 +1,246 @@
+/*
+ * Copyright (c) Facebook, Inc. and its affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#ifdef FB_SONARKIT_ENABLED
+
+#import "FlipperWebSocket.h"
+#import <Flipper/ConnectionContextStore.h>
+#import <Flipper/FlipperTransportTypes.h>
+#import <Flipper/Log.h>
+#import <folly/String.h>
+#import <folly/futures/Future.h>
+#import <folly/io/async/AsyncSocketException.h>
+#import <folly/io/async/SSLContext.h>
+#import <folly/json.h>
+#import <cctype>
+#import <iomanip>
+#import <sstream>
+#import <stdexcept>
+#import <string>
+#import <thread>
+#import "FlipperPlatformWebSocket.h"
+
+namespace facebook {
+namespace flipper {
+
+class WebSocketSerializer : public FlipperPayloadSerializer {
+ public:
+  void put(std::string key, std::string value) override {
+    object_[key] = value;
+  }
+  void put(std::string key, int value) override {
+    object_[key] = value;
+  }
+  std::string url_encode(const std::string& value) {
+    std::ostringstream escaped;
+    escaped.fill('0');
+    escaped << std::hex;
+
+    for (std::string::const_iterator i = value.begin(), n = value.end(); i != n;
+         ++i) {
+      std::string::value_type c = (*i);
+
+      // Keep alphanumeric and other accepted characters intact
+      if (std::isalnum(c) || c == '-' || c == '_' || c == '.' || c == '~') {
+        escaped << c;
+        continue;
+      }
+
+      // Any other characters are percent-encoded
+      escaped << std::uppercase;
+      escaped << '%' << std::setw(2) << int((unsigned char)c);
+      escaped << std::nouppercase;
+    }
+
+    return escaped.str();
+  }
+  std::string serialize() override {
+    std::string query = "";
+    bool append = false;
+
+    for (auto& pair : object_.items()) {
+      auto key = pair.first.asString();
+      auto value = pair.second.asString();
+      if (append) {
+        query += "&";
+      }
+      query += key;
+      query += "=";
+      if (key == "csr") {
+        NSString* csr = [NSString stringWithUTF8String:value.c_str()];
+        NSData* data = [csr dataUsingEncoding:NSUTF8StringEncoding];
+        NSString* base64 = [data base64EncodedStringWithOptions:0];
+
+        query += base64.UTF8String;
+      } else {
+        query += url_encode(value);
+      }
+      append = true;
+    }
+
+    return query;
+  }
+  ~WebSocketSerializer() {}
+
+ private:
+  folly::dynamic object_ = folly::dynamic::object();
+};
+
+FlipperWebSocket::FlipperWebSocket(
+    FlipperConnectionEndpoint endpoint,
+    std::unique_ptr<FlipperSocketBasePayload> payload,
+    folly::EventBase* eventBase)
+    : endpoint_(std::move(endpoint)),
+      payload_(std::move(payload)),
+      eventBase_(eventBase) {}
+
+FlipperWebSocket::FlipperWebSocket(
+    FlipperConnectionEndpoint endpoint,
+    std::unique_ptr<FlipperSocketBasePayload> payload,
+    folly::EventBase* eventBase,
+    ConnectionContextStore* connectionContextStore)
+    : endpoint_(std::move(endpoint)),
+      payload_(std::move(payload)),
+      eventBase_(eventBase),
+      connectionContextStore_(connectionContextStore) {}
+
+void FlipperWebSocket::setEventHandler(SocketEventHandler eventHandler) {
+  eventHandler_ = std::move(eventHandler);
+}
+
+void FlipperWebSocket::setMessageHandler(SocketMessageHandler messageHandler) {
+  messageHandler_ = std::move(messageHandler);
+}
+
+bool FlipperWebSocket::connect(FlipperConnectionManager* manager) {
+  if (socket_ != NULL) {
+    return true;
+  }
+
+  std::string connectionURL = endpoint_.secure ? "wss://" : "ws://";
+  connectionURL += endpoint_.host;
+  connectionURL += ":";
+  connectionURL += std::to_string(endpoint_.port);
+
+  auto serializer = WebSocketSerializer{};
+  payload_->serialize(serializer);
+  auto payload = serializer.serialize();
+
+  if (payload.size()) {
+    connectionURL += "?";
+    connectionURL += payload;
+  }
+
+  __block bool fullfilled = false;
+  __block std::promise<bool> promise;
+  auto connected = promise.get_future();
+
+  NSURL* urlObjc = [NSURL
+      URLWithString:[NSString stringWithUTF8String:connectionURL.c_str()]];
+
+  auto eventHandler = eventHandler_;
+  socket_ = [[FlipperPlatformWebSocket alloc] initWithURL:urlObjc];
+  socket_.eventHandler = ^(SocketEvent event) {
+    /**
+       Only fulfill the promise the first time the event handler is used. If the
+       open event is received, then set the promise value to true. For any other
+       event, consider a failure and set to false.
+     */
+    if (!fullfilled) {
+      fullfilled = true;
+      if (event == SocketEvent::OPEN) {
+        promise.set_value(true);
+      } else {
+        promise.set_value(false);
+      }
+    }
+    eventHandler(event);
+  };
+  socket_.messageHandler = ^(const std::string& message) {
+    this->messageHandler_(message);
+  };
+
+  if (endpoint_.secure) {
+    socket_.certificateProvider = [this](
+                                      char* _Nonnull password, size_t length) {
+      auto pkcs12 = connectionContextStore_->getCertificate();
+      if (pkcs12.first.length() == 0) {
+        return std::string("");
+      }
+      strncpy(password, pkcs12.second.c_str(), length);
+      return pkcs12.first;
+    };
+  }
+
+  eventBase_->runInEventBaseThread([this]() { [socket_ connect]; });
+
+  auto state = connected.wait_for(std::chrono::seconds(10));
+  if (state == std::future_status::ready) {
+    return connected.get();
+  }
+
+  disconnect();
+  return false;
+}
+
+void FlipperWebSocket::disconnect() {
+  eventBase_->runInEventBaseThread([this]() {
+    [socket_ disconnect];
+    socket_ = NULL;
+  });
+}
+
+void FlipperWebSocket::send(
+    const folly::dynamic& message,
+    SocketSendHandler completion) {
+  if (socket_ == NULL) {
+    return;
+  }
+  std::string json = folly::toJson(message);
+  send(json, std::move(completion));
+}
+
+void FlipperWebSocket::send(
+    const std::string& message,
+    SocketSendHandler completion) {
+  if (socket_ == NULL) {
+    return;
+  }
+  NSString* messageObjc = [NSString stringWithUTF8String:message.c_str()];
+  [socket_ send:messageObjc error:NULL];
+  completion();
+}
+
+/**
+    Only ever used for insecure connections to receive the device_id from a
+    signCertificate request. If the intended usage ever changes, then a better
+    approach needs to be put in place.
+ */
+void FlipperWebSocket::sendExpectResponse(
+    const std::string& message,
+    SocketSendExpectResponseHandler completion) {
+  if (socket_ == NULL) {
+    return;
+  }
+  NSString* messageObjc = [NSString stringWithUTF8String:message.c_str()];
+
+  [socket_ setMessageHandler:^(const std::string& msg) {
+    completion(msg, false);
+    [socket_ setMessageHandler:NULL];
+  }];
+  NSError* error = NULL;
+  [socket_ send:messageObjc error:&error];
+
+  if (error != NULL) {
+    completion(error.description.UTF8String, true);
+  }
+}
+
+} // namespace flipper
+} // namespace facebook
+
+#endif